Simple Applescript for Luma Range layers
Trying to write a script to make two Luma range layers on a selected variant - one named DL to select shadows and one named BL to select highlights. But not succeeding - can anyone help?
Thanks!
-
Hi Richard,
It's a good idea to post your code/effort in the post so users can see your approach and guide you where necessary.
Best,
0 -
Thanks Jim. However I’ve nothing that even begins to compile as yet so I didn’t think it worthwhile!
This was my starting point, a simple script for dodge and burn layers, but haven't been able to adapt it to make a luma range layer -
tell application "Capture One 20"
tell layers of primary variant
set NewLayerD to make new layer with properties {name:"D", kind:adjustment, opacity:100} at end
tell adjustments of NewLayerD
set exposure to 0.25
set shadow recovery to 50
end tell
set NewLayerB to make new layer with properties {name:"B", kind:adjustment, opacity:100} at end
tell adjustments of NewLayerB
set exposure to -0.5
set highlight adjustment to -50
end tell
end tell
end tell
0 -
Thank you Eric. By adapting a dehaze script found via Thomas Fitzgerald, I've got this to work! Still tweaking the luma range and adjustment values for best results but this does what I wanted - it's then easy and quick to fine tune the luma mask values if needed - and it's pasteable, but quicker I think to run the script.
tell application "Capture One 20"
tell layers of primary variant
set BLumaLayer to make new layer with properties {name:"B Luma", kind:adjustment, opacity:100} at end
-- set luma range
tell luma range of BLumaLayer
set range high to 255
set range low to 214
set falloff low to 140
--set falloff high to 255
end tell
tell BLumaLayer
fill mask
end tell
tell adjustments of BLumaLayer
set brightness to -20
set highlight adjustment to -30
end tell
set DLumaLayer to make new layer with properties {name:"D Luma", kind:adjustment, opacity:50} at end
-- set luma range
tell luma range of DLumaLayer
set range high to 60
set range low to 40
set falloff low to 20
set falloff high to 100
end tell
tell DLumaLayer
fill mask
end tell
tell adjustments of DLumaLayer
set brightness to 20
set shadow recovery to 10
set black recovery to -5
set contrast to 15
end tell
end tell
end tell
0 -
Hi Richard
I had to delete my original comment as I tried formatting it and it became an unrecoverable mess.
I see what is happening - the layer becomes a Luma layer, and Luma Range is applied, as soon as the value of Range High or Range Low is set.
0 -
Indeed Eric! Anyway this works well for me though doubtless with your ability you could make it cooler . . .
0 -
By limiting the number of 'tell's to the api this is potentially faster
tell application "Capture One 20"
tell primary variant
set BLumaLayer to (make new layer with properties {name:"B Luma", kind:adjustment, opacity:100})
BLumaLayerfill mask
tell luma range of BLumaLayer to set {range high, range low, falloff low} to {255, 214, 140}
tell adjustments of BLumaLayer to set {brightness, highlight adjustment} to {-20, -30}
set DLumaLayer to (make new layer with properties {name:"D Luma", kind:adjustment, opacity:50})
DLumaLayerfill mask
tell luma range of DLumaLayer to set {range high, range low, falloff low, falloff high} to {60, 40, 20, 100}
tell adjustments of DLumaLayer to set {brightness, shadow recovery, black recovery, contrast} to {20, 10, -5, 15}
end tell
end tell
0 -
Thanks Rick - interesting to see another way of writing this.
But on my set up it runs on average about 20% slower . . .
0 -
Haha that’s what I love about development. I get the opposite results. 🤯
0 -
Excellent! I'm running both from script debugger rather than inside C0 . . . going to try on laptop later.
0
Post ist für Kommentare geschlossen.
Kommentare
9 Kommentare